e623451c6a840c1400ec116d94cafc28c27d1b1d
[openwrt-10.03/.git] / scripts / feeds
1 #!/usr/bin/perl
2 use Getopt::Std;
3 use FindBin;
4 use Cwd;
5 use lib "$FindBin::Bin";
6 use metadata;
7 use warnings;
8 use strict;
9 use Cwd 'abs_path';
10
11 chdir "$FindBin::Bin/..";
12 $ENV{TOPDIR}=getcwd();
13
14 my $mk=`which gmake`;   # select the right 'make' program
15 chomp($mk);             # trim trailing newline
16 $mk or $mk = "make";    # default to 'make'
17
18 # check version of make
19 my @mkver = split /\s+/, `$mk -v`, 4;
20 my $valid_mk = 1;
21 $mkver[0] =~ /^GNU/ or $valid_mk = 0;
22 $mkver[1] =~ /^Make/ or $valid_mk = 0;
23 $mkver[2] >= "3.81" or $valid_mk = 0;
24 $valid_mk or die "Unsupported version of make found: $mk\n";
25
26 my @feeds;
27 my %build_packages;
28 my %installed;
29 my %feed_cache;
30
31 my $feed_package = {};
32 my $feed_src = {};
33
34 sub parse_config() {
35         my $line = 0;
36         my %name;
37
38         open FEEDS, "feeds.conf" or
39                 open FEEDS, "feeds.conf.default" or
40                 die "Unable to open feeds configuration";
41         while (<FEEDS>) {
42                 chomp;
43                 s/#.+$//;
44                 next unless /\S/;
45                 my @line = split /\s+/, $_, 3;
46                 my @src;
47                 $line++;
48
49                 my $valid = 1;
50                 $line[0] =~ /^src-\w+$/ or $valid = 0;
51                 $line[1] =~ /^\w+$/ or $valid = 0;
52                 @src = split /\s+/, $line[2];
53                 $valid or die "Syntax error in feeds.conf, line: $line\n";
54
55                 $name{$line[1]} and die "Duplicate feed name '$line[1]', line: $line\n";
56                 $name{$line[1]} = 1;
57
58                 push @feeds, [$line[0], $line[1], \@src];
59         }
60         close FEEDS;
61 }
62
63 sub update_location($$)
64 {
65         my $name = shift;
66         my $url  = shift;
67         my $old_url;
68
69         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
70
71         if( open LOC, "< ./feeds/$name.tmp/location" )
72         {
73                 chomp($old_url = readline LOC);
74                 close LOC;
75         }
76
77         if( !$old_url || $old_url ne $url )
78         {
79                 if( open LOC, "> ./feeds/$name.tmp/location" )
80                 {
81                         print LOC $url, "\n";
82                         close LOC;
83                 }
84                 return $old_url ? 1 : 0;
85         }
86
87         return 0;
88 }
89
90 sub update_index($)
91 {
92         my $name = shift;
93
94         -d "./feeds/$name.tmp" or mkdir "./feeds/$name.tmp" or return 1;
95         -d "./feeds/$name.tmp/info" or mkdir "./feeds/$name.tmp/info" or return 1;
96
97         system("$mk -s prepare-mk TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
98         system("$mk -s -f include/scan.mk IS_TTY=1 SCAN_TARGET=\"packageinfo\" SCAN_DIR=\"feeds/$name\" SCAN_NAME=\"package\" SCAN_DEPS=\"$ENV{TOPDIR}/include/package*.mk\" SCAN_DEPTH=5 SCAN_EXTRA=\"\" TMP_DIR=\"$ENV{TOPDIR}/feeds/$name.tmp\"");
99         system("ln -sf $name.tmp/.packageinfo ./feeds/$name.index");
100
101         return 0;
102 }
103
104 my %update_method = (
105         'src-svn' => {
106                 'init'          => "svn checkout '%s' '%s'",
107                 'update'        => "svn update",
108                 'controldir'    => ".svn"},
109         'src-cpy' => {
110                 'init'          => "cp -Rf '%s' '%s'",
111                 'update'        => ""},
112         'src-link' => {
113                 'init'          => "ln -s '%s' '%s'",
114                 'update'        => ""},
115         'src-git' => {
116                 'init'          => "git clone --depth 1 '%s' '%s'",
117                 'init_branch'   => "git clone --depth 1 --branch '%s' '%s' '%s'",
118                 'update'        => "git pull",
119                 'controldir'    => ".git"},
120         'src-bzr' => {
121                 'init'          => "bzr checkout --lightweight '%s' '%s'",
122                 'update'        => "bzr update",
123                 'controldir'    => ".bzr"},
124         'src-hg' => {
125                 'init'          => "hg clone '%s' '%s'",
126                 'update'        => "hg pull --update",
127                 'controldir'    => ".hg"}
128 );
129
130 # src-git: pull broken
131 # src-cpy: broken if `basename $src` != $name
132
133 sub update_feed_via($$$$) {
134         my $type = shift;
135         my $name = shift;
136         my $src = shift;
137         my $relocate = shift;
138         
139         my $m = $update_method{$type};
140         my $localpath = "./feeds/$name";
141         my $safepath = $localpath;
142         $safepath =~ s/'/'\\''/;
143         my ($base, $branch) = split(/;/, $src, 2);
144
145         if( $relocate || !$m->{'update'} || !-d "$localpath/$m->{'controldir'}" ) {
146                 system("rm -rf '$safepath'");
147                 if ($m->{'init_branch'} and $branch) {
148                         system(sprintf($m->{'init_branch'}, $branch, $base, $safepath)) == 0 or return 1;
149                 } else {
150                         system(sprintf($m->{'init'}, $src, $safepath)) == 0 or return 1;
151                 }
152         } else {
153                 system("cd '$safepath'; $m->{'update'}") == 0 or return 1;
154         }
155         
156         return 0;
157 }
158
159 sub get_feed($) {
160         my $feed = shift;
161
162         if (!defined($feed_cache{$feed})) {
163                 my $file = "./feeds/$feed.index";
164
165                 clear_packages();
166                 -f $file or do {
167                         print "Ignoring feed '$feed' - index missing\n";
168                         return;
169                 };
170                 parse_package_metadata($file) or return;
171                 $feed_cache{$feed} = [ { %package }, { %srcpackage } ];
172         }
173
174         $feed_package = $feed_cache{$feed}->[0];
175         $feed_src = $feed_cache{$feed}->[1];
176         return $feed_cache{$feed}->[0];
177 }
178
179 sub get_installed() {
180         system("$mk -s prepare-tmpinfo");
181         clear_packages();
182         parse_package_metadata("./tmp/.packageinfo");
183         %installed = %package;
184 }
185
186 sub search_feed {
187         my $feed = shift;
188         my @substr = @_;
189         my $display;
190
191         return unless @substr > 0;
192         get_feed($feed);
193         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
194                 my $pkg = $feed_package->{$name};
195                 my $substr;
196                 my $pkgmatch = 1;
197
198                 next if $pkg->{vdepends};
199                 foreach my $substr (@substr) {
200                         my $match;
201                         foreach my $key (qw(name title description src)) {
202                                 $pkg->{$key} and $substr and $pkg->{$key} =~ m/$substr/i and $match = 1;
203                         }
204                         $match or undef $pkgmatch;
205                 };
206                 $pkgmatch and do {
207                         $display or do {
208                                 print "Search results in feed '$feed':\n";
209                                 $display = 1;
210                         };
211                         printf "\%-25s\t\%s\n", $pkg->{name}, $pkg->{title};
212                 };
213         }
214         return 0;
215 }
216
217 sub search {
218         my %opts;
219
220         getopt('r:', \%opts);
221         foreach my $feed (@feeds) {
222                 search_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
223         }
224 }
225
226 sub list_feed {
227         my $feed = shift;
228
229         get_feed($feed);
230         foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
231                 my $pkg = $feed_package->{$name};
232                 next if $pkg->{vdepends};
233                 if($pkg->{name}) {
234                         printf "\%-32s\t\%s\n", $pkg->{name}, $pkg->{title};
235                 }
236         }
237
238         return 0;
239 }
240
241 sub list {
242         my %opts;
243
244         getopts('r:sh', \%opts);
245         if ($opts{h}) {
246                 usage();
247                 return 0;
248         }
249         if ($opts{s}) {
250                 foreach my $feed (@feeds) {
251                         printf "\%-32s\tURL: %s\n", $feed->[1], join(", ", @{$feed->[2]});
252                 }
253                 return 0;
254         }
255         foreach my $feed (@feeds) {
256                 list_feed($feed->[1], @ARGV) if (!defined($opts{r}) or $opts{r} eq $feed->[1]);
257         }
258         return 0;
259 }
260
261 sub install_generic() {
262         my $feed = shift;
263         my $pkg = shift;
264         my $path = $pkg->{makefile};
265
266         if($path) {
267                 $path =~ s/\/Makefile$//;
268
269                 -d "./package/feeds" or mkdir "./package/feeds";
270                 -d "./package/feeds/$feed->[1]" or mkdir "./package/feeds/$feed->[1]";
271                 system("ln -sf ../../../$path ./package/feeds/$feed->[1]/");
272         } else {
273                 warn "Package is not valid\n";
274                 return 1;
275         }
276
277         return 0;
278 }
279
280 my %install_method = (
281         'src-svn' => \&install_generic,
282         'src-cpy' => \&install_generic,
283         'src-link' => \&install_generic,
284         'src-git' => \&install_generic,
285         'src-bzr' => \&install_generic,
286         'src-hg' => \&install_generic,
287 );
288
289 my %feed;
290
291 sub lookup_package($$) {
292         my $feed = shift;
293         my $package = shift;
294
295         foreach my $feed ($feed, @feeds) {
296                 next unless $feed->[1];
297                 next unless $feed{$feed->[1]};
298                 $feed{$feed->[1]}->{$package} and return $feed;
299         }
300         return;
301 }
302
303 sub install_package {
304         my $feed = shift;
305         my $name = shift;
306         my $ret = 0;
307
308         $feed = lookup_package($feed, $name);
309         $feed or do {
310                 $installed{$name} and return 0;
311                 # TODO: check if it's already installed within ./package directory
312                 $feed_src->{$name} or -d "./package/$name" or warn "WARNING: No feed for package '$name' found, maybe it's already part of the standard packages?\n";
313                 return 0;
314         };
315
316         # switch to the metadata for the selected feed
317         get_feed($feed->[1]);
318
319         my $pkg = $feed{$feed->[1]}->{$name} or return 1;
320         $pkg->{name} or do {
321                 $installed{$name} and return 0;
322                 # TODO: check if this is an alias package, maybe it's known by another name
323                 warn "WARNING: Package '$name' is not available in feed $feed->[1].\n";
324                 return 0;
325         };
326         my $src = $pkg->{src};
327         my $type = $feed->[0];
328         $src or $src = $name;
329
330         # previously installed packages set the runtime package
331         # newly installed packages set the source package
332         $installed{$src} and return 0;
333
334         # check previously installed packages
335         $installed{$name} and return 0;
336         $installed{$src} = 1;
337         warn "Installing package '$src'\n";
338
339         $install_method{$type} or do {
340                 warn "Unknown installation method: '$type'\n";
341                 return 1;
342         };
343
344         &{$install_method{$type}}($feed, $pkg) == 0 or do {
345                 warn "failed.\n";
346                 return 1;
347         };
348
349         # install all dependencies referenced from the source package
350         foreach my $vpkg (@{$feed_src->{$src}}) {
351                 foreach my $dep (@{$vpkg->{depends}}, @{$vpkg->{builddepends}}, @{$vpkg->{"builddepends/host"}}) {
352                         next if $dep =~ /@/;
353                         $dep =~ s/^\+//;
354                         $dep =~ s/^.+://;
355                         $dep =~ s/\/.+$//;
356                         next unless $dep;
357                         install_package($feed, $dep) == 0 or $ret = 1;
358                 }
359         }
360
361         return $ret;
362 }
363
364 sub refresh_config {
365         my $default = shift;
366
367         # workaround for timestamp check
368         system("rm -f tmp/.packageinfo");
369
370         # refresh the config
371         if ($default) {
372                 system("$mk oldconfig CONFDEFAULT=\"$default\" Config.in >/dev/null 2>/dev/null");
373         } else {
374                 system("$mk defconfig Config.in >/dev/null 2>/dev/null");
375         }
376 }
377
378 sub install {
379         my $name;
380         my %opts;
381         my $feed;
382         my $ret = 0;
383
384         getopts('ap:d:h', \%opts);
385
386         if ($opts{h}) {
387                 usage();
388                 return 0;
389         }
390
391         get_installed();
392
393         foreach my $f (@feeds) {
394                 # index all feeds
395                 $feed{$f->[1]} = get_feed($f->[1]);
396
397                 # look up the preferred feed
398                 $opts{p} and $f->[1] eq $opts{p} and $feed = $f;
399         }
400
401         if($opts{a}) {
402                 foreach my $f (@feeds) {
403                         if (!defined($opts{p}) or $opts{p} eq $f->[1]) {
404                                 printf "Installing all packages from feed %s.\n", $f->[1];
405                                 get_feed($f->[1]);
406                                 foreach my $name (sort { lc($a) cmp lc($b) } keys %$feed_package) {
407                                         my $p = $feed_package->{$name};
408                                         next if $p->{vdepends};
409                                         if( $p->{name} ) {
410                                                 install_package($feed, $p->{name}) == 0 or $ret = 1;
411                                                 get_feed($f->[1]);
412                                         }
413                                 }
414                         }
415                 }
416         } else {
417                 while ($name = shift @ARGV) {
418                         install_package($feed, $name) == 0 or $ret = 1;
419                 }
420         }
421
422         # workaround for timestamp check
423
424         # set the defaults
425         if ($opts{d} and $opts{d} =~ /^[ymn]$/) {
426                 refresh_config($opts{d});
427         }
428
429         return $ret;
430 }
431
432 sub uninstall {
433         my %opts;
434         my $name;
435         my $uninstall;
436
437         getopts('ah', \%opts);
438
439         if ($opts{h}) {
440                 usage();
441                 return 0;
442         }
443
444         if ($opts{a}) {
445                 system("rm -rvf ./package/feeds");
446                 $uninstall = 1;
447         } else {
448                 if($#ARGV == -1) {
449                         warn "WARNING: no package to uninstall\n";
450                         return 0;
451                 }
452                 get_installed();
453                 while ($name = shift @ARGV) {
454                         my $pkg = $installed{$name};
455                         $pkg or do {
456                                 warn "WARNING: $name not installed\n";
457                                 next;
458                         };
459                         $pkg->{src} and $name = $pkg->{src};
460                         warn "Uninstalling package '$name'\n";
461                         system("rm -f ./package/feeds/*/$name");
462                         $uninstall = 1;
463                 }
464         }
465         $uninstall and refresh_config();
466         return 0;
467 }
468
469 sub update_feed($$$$)
470 {
471         my $type=shift;
472         my $name=shift;
473         my $src=shift;
474         my $perform_update=shift;
475         my $force_relocate=update_location( $name, "@$src" );
476
477         if( $force_relocate ) {
478                 warn "Source of feed $name has changed, replacing copy\n";
479         }
480         $update_method{$type} or do {
481                 warn "Unknown type '$type' in feed $name\n";
482                 return 1;
483         };
484         $perform_update and do {
485                 my $failed = 1;
486                 foreach my $feedsrc (@$src) {
487                         warn "Updating feed '$name' from '$feedsrc' ...\n";
488                         next unless update_feed_via($type, $name, $feedsrc, $force_relocate) == 0;
489                         $failed = 0;
490                         last;
491                 }
492                 $failed and do {
493                         warn "failed.\n";
494                         return 1;
495                 };
496         };
497         warn "Create index file './feeds/$name.index' \n";
498         update_index($name) == 0 or do {
499                 warn "failed.\n";
500                 return 1;
501         };
502         return 0;
503 }
504
505 sub update {
506         my %opts;
507         my $feed_name;
508         my $perform_update=1;
509
510         $ENV{SCAN_COOKIE} = $$;
511         $ENV{KBUILD_VERBOSE} = 99;
512
513         getopts('ahi', \%opts);
514
515         if ($opts{h}) {
516                 usage();
517                 return 0;
518         }
519
520         if ($opts{i}) {
521                 # don't update from (remote) repository
522                 # only re-create index information
523                 $perform_update=0;
524         }
525
526         -d "feeds" or do {
527                         mkdir "feeds" or die "Unable to create the feeds directory";
528                 };
529
530         if ( ($#ARGV == -1) or $opts{a}) {
531                 foreach my $feed (@feeds) {
532                         my ($type, $name, $src) = @$feed;
533                         update_feed($type, $name, $src, $perform_update);
534                 }
535         } else {
536                 while ($feed_name = shift @ARGV) {
537                         foreach my $feed (@feeds) {
538                                 my ($type, $name, $src) = @$feed;
539                                 if($feed_name ne $name) {
540                                         next;
541                                 }
542                                 update_feed($type, $name, $src, $perform_update);
543                         }
544                 }
545         }
546
547         refresh_config();
548
549         return 0;
550 }
551
552 sub usage() {
553         print <<EOF;
554 Usage: $0 <command> [options]
555
556 Commands:
557         list [options]: List feeds and their content
558         Options:
559             -s :           List of feed names and their URL.
560             -r <feedname>: List packages of specified feed.
561
562         install [options] <package>: Install a package
563         Options:
564             -a :           Install all packages from all feeds or from the specified feed using the -p option.
565             -p <feedname>: Prefer this feed when installing packages.
566             -d <y|m|n>:    Set default for newly installed packages.
567
568         search [options] <substring>: Search for a package
569         Options:
570             -r <feedname>: Only search in this feed
571
572         uninstall -a|<package>: Uninstall a package
573         Options:
574             -a :           Uninstalls all packages.
575
576         update -a|<feedname(s)>: Update packages and lists of feeds in feeds.conf .
577         Options:
578             -a :           Update all feeds listed within feeds.conf. Otherwise the spezified feeds will be updated.
579             -i :           Recreate the index only. No feed update from repository is performed.
580
581         clean:             Remove downloaded/generated files.
582
583 EOF
584         exit(1);
585 }
586
587 my %commands = (
588         'list' => \&list,
589         'update' => \&update,
590         'install' => \&install,
591         'search' => \&search,
592         'uninstall' => \&uninstall,
593         'clean' => sub {
594                 system("rm -rf feeds");
595         }
596 );
597
598 my $arg = shift @ARGV;
599 $arg or usage();
600 parse_config;
601 foreach my $cmd (keys %commands) {
602         $arg eq $cmd and do {
603                 exit(&{$commands{$cmd}}());
604         };
605 }
606 usage();